How to find all globals in routines?

Question

Question

The task is to find all globals that are referenced in certain routines. I could search for ^ using class(%Studio.Project).FindInFiles but that would also find ^ in comments and function calls. I can distinguish between a global and a function call visually, but it would be lovely to be able to skip function calls programmatically. Is it possible?

The Find and Replace screen in Studio has a capability of searching for ^ with Match Element Type set to Global Variable. Maybe I could use that but what is the ObjectScript function behind this screen if any?

Product version: IRIS 2022.1

Discussion (17)3

Log in or sign up to continue

Julius Kavay · Feb 4

With the help of a standard editor only - that will be a difficult and cumbersome task, for example, in the below snippet try to find the "^Test" global (not the routine ^Test):

 set value = ^Test  // take a value from the global ^Test
 do ^Test           // call the routine ^Test
 
 // a more complex case
 //
 set ref = "^Test"      // in this case you are lucky
 set ref = "^" _ "Test" // this could be a stumbling stone
 // few lines later
 set value = @ref  // get the value of ^Test global
 do @ref           // call the routine ^Test

You will need some kind of an "intelligent" editor which can make a difference between a call (do) like operation and a "get-value" like operation. The one I know of (but I have never used it, so I don't know how good it works) is the RE/parser of GJS. Asking Google is a good starting point.

2 0

Julius Kavay · Feb 7

And do not forget, if the application has/uses parts of "older code" then the so called "naked syntax" may also be a issue (of course not, if you just want to know the name of the global).

Classmethod Test()
{
  kill ^myGlobal
  kill ^yourGlobal
  set ^myGlobal(2)="some data"
  do ..moreData("data1")
  set ^yourGlobal(3)="other data"
  do ..moreData("data2")
  
  // Now, the globals look like
  //
  // ^myGlobal(2)="some data"
  // ^myGlobal(9)="data1"
  //
  // ^yourGlobal(3)="other data"
  // ^yourGlobal(9)="data2"
}

ClassMethod moreData(data)
{
  set ^(9)=data	
}

Beside all the "nice" combinations of direct sets, indirections, naked synates etc. do not forget, your application may call routinies/methods which are in deployed mode (third party APIs and utilities - hopefully with documentation)

0 0

Brett Saviano · Feb 5

@Anna Golitsyna If you goal is to find all globals referenced in a document, you can use a modified version of the code I included in this comment. The code uses the %SyntaxColor class to get a JSON array of semantic tokens for a document, and then loops through them looking for global references. Note that this will only find literal references, not naked references or indirection.

ClassMethod WriteAllGrefs()
{
    Set syn = ##class(%SyntaxColor).%New(), in = ##class(%Stream.TmpCharacter).%New(), out = ##class(%Stream.TmpCharacter).%New()
    #; TODO Put your document's contents into "in"
    Do syn.Color(in,out,"COS" /* or "INT" or "CLS" */,"KE" /* K means JSON output, E means keep empty lines */)
    #; Format of the JSON output:
    #; [
    #;     #; One array for each source line
    #;     [
    #;         {
    #;             #; Language of the token. See Languages() in %Library.SyntaxColor.
    #;             "l": %Integer,
    #;             #; Attribute of the token. See Attributes() in %Library.SyntaxColor.
    #;             "s": %Integer,
    #;             #; Zero-indexed start position of the token on the line
    #;             "p": %Integer,
    #;             #; Length of the token in characters
    #;             "c": %Integer
    #;         }
    #;     ]
    #; ]
    Set json = ##class(%DynamicArray).%FromJSON(out), lineIter = json.%GetIterator()
    While lineIter.%GetNext(.lineNum,.lineTokens) {
        Set tokensIter = lineTokens.%GetIterator()
        While tokensIter.%GetNext(,.token) {
            If (
                #; COS
                (token.l = 1) &&
                #; Global reference
                (token.s = 18)
            ) {
                Write "Gref starting in column ",token.p + 1," of line ",lineNum + 1,!
            }
        }
    }
}

You can combine this with the %Library.RoutineMgr_StudioOpenDialog query to make an index of all globals referenced in a subset of documents.

3 0

Brett Saviano · Feb 6

The issue is that I forgot to add the E/e flag to the list of flags for the Color() method, so empty lines were removed from the JSON output. I will edit the accepted answer.

1 0

score 0 · Answer 1 · 2025-02-05T11:14:59-05:00

Anna Golitsyna · Feb 5

Thanks, Julius

0 0

score 1 · Answer 2 · 2025-02-05T06:43:40-05:00

I recommend using visual studio code (vs-code) where you can search with regex. searching. Consider also seqdhing for 0-n while spaces to elimnate all spaces, tabs etc.
for example: a reference to a global could be:
set ^global( ... )=
s ^global( ... )=
s:cond ^global( ... )=

If combined with other commands: then you should search for the comma (,) e.g.
set var=someting,^global( ...)=

However, use of indirection is very complex to find... (you need to skip 0-n of any characters including new lines between the set and the use of @)

score 0 · Answer 3 · 2025-02-05T11:16:14-05:00

Anna Golitsyna · Feb 5

Thanks, Yaron. I'll skip looking for indirections for now.

0 0

score 0 · Answer 4 · 2025-02-05T11:18:07-05:00

Thanks, Brett. I did try using SyntaxColor but not with JSON and did not like the HTML results. I'll give your code a try.

score 0 · Answer 5 · 2025-02-05T12:28:12-05:00

Excellent, just excellent. It did find correctly all globals in a routine (no indirection). I populated in = ##class(%Stream.TmpCharacter).%New() with this code:
S NumLines=^ROUTINE(routineName,0,0) ; Omit extension
F n=0:1:NumLines {
S line=$T(@routineName+n^@routineName)
D in.Write(line),in.Write($c(13,10))
}
D in.Rewind()

I also added this after your Write:
Set line=$G(^ROUTINE(rtnName,0,lineNum+1))
Write $C(9),$E(line,token.p+1,token.p+token.c),!

I did not try finding globals in classes, but I assume this would be very similar. Is there any online documentation that shows that token value for globals is 18? Would be curious about other token values.

score 1 · Answer 6 · 2025-02-05T13:31:54-05:00

I'm glad you find this useful! Instead of looping through ^ROUTINE or ^rMAC to build the stream, you can open a %Routine object and pass that in as the first argument. That class implements the Stream interface. You can get a list of languages and attributes per language from a %SyntaxColor object using the Languages() and Attributes() methods.

score 0 · Answer 7 · 2025-02-05T16:30:44-05:00

I have an odd problem. In vast majority of cases globals are defined by your code correctly. However, for some routines the lineNum as returned by GetNext is one line count off and the global with the stated token attributes is actually on the next line. I tried to slightly modify such routines and recompile, but it did not always help. Any advice?

score 1 · Answer 8 · 2025-02-05T17:10:34-05:00

Brett Saviano · Feb 5

Can you give me an code snippet?

1 0

score 0 · Answer 9 · 2025-02-05T18:17:23-05:00

I will have time to prepare such a snippet tomorrow, sorry. Meanwhile, it's not necessarily one line off but up to several lines off, a few routines only. In your code, is it possible to extract text of the line for which tokens are calculated? I looked around and did not see such a possibility.

score 0 · Answer 10 · 2025-02-06T10:00:04-05:00

Anna Golitsyna · Feb 6

I just messaged you two snippets. Thanks again.

0 0

score 0 · Answer 11 · 2025-02-07T12:56:47-05:00

Anna Golitsyna · Feb 7

Yes, the problem is gone! Thanks a lot for your help.

0 0

score 0 · Answer 12 · 2025-03-16T16:40:15-04:00

Developer Commu... · Mar 16

💡 This question is considered a Key Question. More details here.

0 0

score 0 · Answer 13 · 2025-03-24T09:22:56-04:00

To find all globals that are referenced in certain routines and skip function calls programmatically, you can use the %SyntaxColor class to get a JSON array of semantic tokens for a document and then loop through them looking for global references. This method will help you distinguish between global references and function calls. Here is a summary of the approach:

Use the %SyntaxColor class to get a JSON array of semantic tokens for a document.
Loop through the tokens to identify global references by checking the token attributes.
This method will only find literal references, not naked references or indirection.

For detailed steps and code examples, refer to the article on finding all globals in routines [1].